>    restart:

The Automobile Problem

Straightforward solution of optimization problem.

R = rebate (so profit per car is 1500-R)

N = number of cars sold

K = number of cars sold without rebate

P = total profit

>    N := ( 1 + R/100*0.15 ) * K;

N := (1+.1500000000e-2*R)*K

>    P := (1500-R) * N;

P := (1500-R)*(1+.1500000000e-2*R)*K

>    dPdR := diff( P, R );

dPdR := -(1+.1500000000e-2*R)*K+.1500000000e-2*(1500-R)*K

>    dPdR := simplify( diff( P, R ) );

dPdR := 1.250000000*K-.3000000000e-2*K*R

The optimal rebate is ...

>    Rstar := solve( dPdR=0, R );

Rstar := 416.6666667

Total profit with optimal rebate is ...

>    Pstar := subs( R=Rstar, P );

Pstar := 1760.416666*K

Number of cars sold with optimal rebate is ...

>    Nstar := subs( R=Rstar, N );

Nstar := 1.625000000*K

That's a lot of extra cars!

The car manufacturer will want to know the impact of the optimal rebate on the number of cars that will need to be manufactured!

Graphical sensitivity analysis.

i = increase in sales  (in percent, so i was set to 15 in the model above)

>    N := ( 1 + R/100*i/100 ) * K;

N := (1+1/10000*R*i)*K

>    P := (1500-R) * N;

P := (1500-R)*(1+1/10000*R*i)*K

>    dPdR := simplify( diff( P, R ) );

dPdR := -K-1/5000*K*R*i+3/20*i*K

>    Rstar := solve( dPdR=0, R );

Rstar := 250*(-20+3*i)/i

So we now know how Rstar depends on i.  

A visual representation of this formula would be helpful.  

What does a graph of Rstar versus i look like?

>    plot( Rstar, i = 0.. 30, -100..1000, color=black );

[Maple Plot]

Interesting.

The model says that if sales only increase say 5% for every $100 of rebate offered, then it is best not to offer any rebate!

Where is the exact cutoff?

Set Rstar to zero, and solve for i ...

>    solve( Rstar=0, i );

20/3

Also, it appears that the amount of rebate levels off, even if sales really increase with every $100 of rebate offered.

Investigate the asymptotic value of the rebate with a limit ...

>    limit( Rstar, i=infinity );

750

This says that the automobile manufacturer never needs to offer a rebate greater than $750, no matter how eager people are to buy a car when a rebate is offered.  That also seems like a worthwhile bit of information to pass back to the car manufacturer.

We can also investigate how the total profit and the total number of cars sold under optimal conditions depend on the value of i.

By optimal conditions, we mean with the rebate offered being equal to Rstar.

>    Pstar := subs( R=Rstar, P );

Pstar := (1500-250*(-20+3*i)/i)*(1/2+3/40*i)*K

>    Nstar := subs( R=Rstar, N );

Nstar := (1/2+3/40*i)*K

Note that we cannot plot P nor N, since these functions involve K for which we have no value.  

But K is just a scaling factor, and we can scale it out.

>    plot( Pstar/K, i=0..30, color=black );

[Maple Plot]

>    plot( Nstar/K, i=0..30, color=black );

[Maple Plot]

Quantitative sensitivity analysis, using the definition of S(x,r).

>    sens_R_i := diff( Rstar, i ) * i / Rstar;

sens_R_i := 1/250*(750/i-250*(-20+3*i)/i^2)*i^2/(-20+3*i)

>    subs( i=15, sens_R_i );

4/5

>    sens_P_i := diff( Pstar, i ) * i / Pstar;

sens_P_i := ((-750/i+250*(-20+3*i)/i^2)*(1/2+3/40*i)*K+3/40*(1500-250*(-20+3*i)/i)*K)*i/(1500-250*(-20+3*i)/i)/(1/2+3/40*i)/K

>    subs( i=15, sens_P_i );

5/13

>    sens_N_i := diff( Nstar, i ) * i / Nstar;

sens_N_i := 3/40*i/(1/2+3/40*i)

>    subs( i=15, sens_N_i );

9/13

The manufacturer might want to see some specific values for the rebate, the profit, and the number of cars sold under different conditions, say i =10, 15, 20 ...

>    subs( i=10, [Rstar, Pstar, Nstar ] );

[250, 3125/2*K, 5/4*K]

>    evalf(%);

[250., 1562.500000*K, 1.250000000*K]

>    evalf( subs( i=15, [ Rstar, Pstar, Nstar ] ) );

[416.6666667, 1760.416667*K, 1.625000000*K]

>    evalf( subs( i=20, [ Rstar, Pstar, Nstar ] ) );

[500., 2000.*K, 2.*K]

>